$include (C8051F410.INC)

DSEG at 020h
	i:	DS 1	; running index, 0..255
	n:	DS 1	; duty cycle parameter, n/256
	dn:	DS 1	; step of changing the duty cycle parameter

LED 	EQU		P0.2

CSEG at 0000h
	jmp Main

ORG 000Bh
	jmp 	Timer0IRQ

ORG 002Bh
	jmp 	Timer2IRQ

Timer0IRQ:				; Timer 2 interrupt routine
	push 	acc			; save accumulator
	push 	psw			; save program status word
	clr		TF0			; clear overflow flag
	mov 	TH0,#0B0h	; repeat time = 65536-(TH0*256+TL0)/(sysclk/12)
	mov 	TL0,#040h	; 
	mov 	a,n			; n=n+dn
	add 	a,dn		;
	mov 	n,a			; 
	pop 	psw			; restore program status word
	pop 	acc			; restore accumulator
	reti

Timer2IRQ:				; Timer 2 interrupt routine
	push 	acc			; save accumulator
	push 	psw			; save program status word
	mov  	TMR2CN,#04h	; clear interrupt flag
	inc 	i			; increment variable
	mov 	a,n			; 
	clr 	c			; clear carry flag
	subb	a,i			; calculate n-i
	mov 	LED,c		; c=1, if n<i, use it to switch the LED on/off
	pop 	psw			; restore program status word
	pop 	acc			; restore accumulator
	reti

Main:
    anl		PCA0MD,    #0BFh	; watchdog off
    mov		PCA0MD,    #000h
    mov		XBR1,      #040h	; crossbar on

	mov 	TMOD,#001h 			; Timer 0 mode is 16-bit timer
	mov 	TH0,#0B0h			; wait time = 65536-(TH0*256+TL0)/(sysclk/12)
	mov 	TL0,#040h			; 

    mov  	TMR2RLL,   #080h	; reload value of counter
    mov  	TMR2RLH,   #0FFh	
    mov  	TMR2L,     TMR2RLL	; initial value of counter
    mov  	TMR2H,     TMR2RLH

	mov  	OSCICN,    #087h	; oscillator 24,5MHz

	mov 	i,	#0				; initial value
	mov 	n,	#10				; initial value
	mov 	dn,	#2				; initial value

    mov  	IE,#0A2h			; enable interrupts
	setb	TR0					; start timer 0
    mov  	TMR2CN,    #004h	; start timer 2


Repeat:
	jmp 	Repeat				; repeat forever

END